How to send email with Lotus Notes

It is pretty easy if you have VBA routine. Link from IBM site will give you one. And here one from my application:

Public Function SendNotesMail(strTo As String, _

    strSubject As String, strBody As String, _

    strFileName As String, ParamArray strFiles()) As Boolean

    'Usage:

    'SendNotesMail "SteveO@microsoft.com", _

        "subj", "some body", "c:\filename.txt"

 

    Dim doc As Object   'Lotus NOtes Document

    Dim rtitem As Object '

    Dim Body2 As Object

    Dim ws As Object    'Lotus Notes Workspace

    Dim oSess As Object 'Lotus Notes Session

    Dim oDB As Object   'Lotus Notes Database

    Dim X As Integer    'Counter

 

    Set oSess = CreateObject("Notes.NotesSession")

    'access the logged on users mailbox

    Set oDB = oSess.GETDATABASE("", "")

    Call oDB.OPENMAIL

 

    'create a new document as add text

    Set doc = oDB.CREATEDOCUMENT

    Set rtitem = doc.CREATERICHTEXTITEM("Body")

    doc.sendto = strTo

    'doc.CopyTo = CCToAdr

    'doc.BlindCopyTo = BCCToAdr

    doc.Subject = strSubject

    doc.Body = strBody & vbCrLf & vbCrLf

 

    'attach files

    If strFileName <> "" Then

        Set Body2 = rtitem.EMBEDOBJECT(1454, "", strFileName)

        If UBound(strFiles) > -1 Then

            For X = 0 To UBound(strFiles)

                Set Body2 = rtitem.EMBEDOBJECT(1454, "", strFiles(X))

            Next X

        End If

    End If

    doc.SAVEMESSAGEONSEND = True

    doc.SEND False

 

    SendNotesMail = True

End Function